@echo off

: = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
: Filename: AutoExec.bat
:  Purpose: Multi NIC DOS NDIS Boot Disk
:           Uses DHCP to get IP address.
:           Loads Ghost. Images split into 690 MB parts.
:    Notes: This autoexec.bat can be used for all DOS NDIS boot disks.
:      Tip: If you're unable to bind to the NIC driver, disable PnP OS in BIOS
:      Tip: If Ghost.exe hangs on a system with SATA drives, try changing the 
:           SATA operation settings to "Combination" in the BIOS.
:  Revised: 2/11/2006, 4/9/2006
: = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =

prompt $p$g

path=a:\;r:\;r:\command;r:\ut

echo.

: Load MS-DOS LAN Manager v2.1
\net\NETBIND

echo.
echo - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
echo      DOS NDIS Boot Disk (Ghost)
echo. 
echo      Uses DHCP to get an IP address
echo      Dumps will -split=690 and -z2 (high compression)
echo - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

echo.
echo      Loading MSCDEX.exe to enable access to CD-ROM (Drive R)
echo. 
 mscdex.exe /d:mscd001 /l:r /m:16
: mscdex.exe /d:mscd001 /l:r /m:16 /v

echo.

mouse > nul:

:ASK
echo.
echo.

choice /C:LCE Load disk from image file, Create new image file˙or Exit˙
if errorlevel 3 if not errorlevel 4 goto done
if errorlevel 2 if not errorlevel 3 set op=dump
if errorlevel 1 if not errorlevel 2 set op=load
if @%op%==@ goto env_err

echo.

choice /C:NY Add the -FNI parameter to Ghost?˙(N or Y)
if errorlevel 2 if not errorlevel 3 set fni=-FNI
if errorlevel 1 if not errorlevel 2 set fni=


ECHO.
ECHO.
STRINGS SNAME = ASK Please Enter The Session Name You Want To Join˙,30
IF @%SNAME%==@ GOTO ENV_ERR

ECHO.
ECHO.

IF @%op%==@dump ECHO Operation Type = Create New Image File
IF @%op%==@load ECHO Operation Type = Load Disk From Image File
ECHO Session Name = %SNAME% ,( %FNI% )
ECHO. 

CHOICE Are Your Entries Correct˙
if errorlevel 2 goto ASK
rem When WATTCP.CFG is missing and IP address, Ghost uses DHCP.

:START

if not exist r:\ghost.exe goto NoGhost
r:

echo.
echo      Loading...  Ghost...
echo.

IF @%op%==@load GHOST.exe -CLONE,SRC=@MC%SNAME%,dst=1 -BATCH -SURE %FNI%
IF @%op%==@dump GHOST.exe -CLONE,DST=@MC%SNAME%,SRC=1 -split=690 -auto -z2 -SURE %FNI%
   rem -z2        enables high compression
   rem -split=690 splits image files into 690 MB parts
   rem -auto      Automatically names the additional parts
   rem -SURE      Do not ask for confirmation before starting
   rem -FNI       Needed for some Serial ATA systems and some Intel PRO/1000 MT's


GOTO Done

:NoGhost
echo.
echo      Ghost.exe is missing.
echo.
GOTO Done

:ENV_ERR
rem CLS
ECHO.
ECHO.
ECHO Error Accessing Required Environment Variable - Program Aborting ! ! !
ECHO.
pause
goto Done

:Done